#!/bin/csh -f
#
# Get your last home disk usage in kilobytes.
# Usage:  mydu [user1 user2...]
# CUSG/larsrohr, 03/07.

#
# Make sure we run this on a host that has access to the logs
#
switch (`hostname`)
  case freebie.EECS.Berkeley.EDU:
  case janus.EECS.Berkeley.EDU:
    breaksw
  default:
    ssh janus.eecs.berkeley.edu $0 $argv
    exit 0
endsw



#
# We need gdate to effectively get yesterday's date
#
switch (`uname`)
  case SunOS:
    set DATE = /project/eecs/cusg-clients/files/solaris.gdate
    breaksw
  case FreeBSD:
    set DATE = /usr/local/bin/gdate
    breaksw
  default:
    echo "I work in Solaris and FreeBSD"
    exit 1
endsw


#set LOCATION = /usr/sww/share/adm/du/coeus-user
#set newest = `ls -t1 ${LOCATION}/??.??.?? | head -1`
set LOCATION = /project/eecs/idsg/billing/home-eecs
set SUBDIR = `$DATE -d yesterday +'%Y'`/`$DATE -d yesterday +'%m'`
set newest = ${LOCATION}/${SUBDIR}/`$DATE -d yesterday +'%m.%d.%y'`


if ( $#argv == 0 ) then
	if ( $?USER ) then
		set userlist = $USER
	else
		set userlist = $LOGNAME
	endif
else
	set userlist = " $argv "
endif

foreach user ( $userlist )
	grep \	${user}$ $newest
	set STATUS = $status
end

# exit with status of last grep
exit $STATUS